JMail 元件配合表單寄送電子郵件範例說明

JMail 元件是本公司 Windows 系列伺服器支援的寄信元件之一，利用本元件您可於 ASP 程式中呼叫該元件達到寄信給自己或使用者的功能，以下簡單介紹搭配一表單收集使用者資訊並配合寄信的程式碼，利用該程式即可有效的從網頁上收集或聯絡網站訪客資料或意見的目的：

JMailForm.html ( 供網站訪客填寫用的表單 )：

<html>
<head>
<title>JMail 電子郵件表單</title>
</head>
<body>
<form method="post" action="SendMail.asp">
請填寫以下資料並按寄出鍵即可
<br><br>
姓名<br>
<input type="text" size="25" name="name"><br>

電子郵件位址<br>
<input type="text" size="25" name="email"><br>
主旨<br>
<select name="subject" size="1">
<option value="help">help
<option value="tips">tips
<option value="other">other
</select>
<br>詳細內容<br>
<textarea name="body" cols="40" rows="15" wrap="PHYSICAL"></textarea>
<br>
<input type="submit" value="寄出">
</form>
</body>
</html>


SendMail.Asp ( 收集網站訪客填寫的表單並轉寄成電子郵件)：

<%@LANGUAGE = VBSCRIPT%>
<html>
<body>
<%
recipient = "you@email.com" '此處為收信人的電子郵件位址
' 取得表單資料
name = Request.Form("name")
senderEmail = Request.Form("email")
subject = "Regarding " & Request.Form("subject")
body = Request.Form("body")

' 建立 JMail 元件宣告
set msg = Server.CreateOBject( "JMail.Message" )

' 設定將寄信的過程紀錄下來
msg.Logging = true
msg.silent = true

' 中文編碼設定 *請一定要加入下面四行才能正常顯示中文*
msg.Charset = "big5"
msg.ContentTransferEncoding = "base64"
msg.Encoding = "base64"
msg.ISOEncodeHeaders = false

' 將填寫表單資料的訪客資料存入元件中
msg.From = senderEmail
msg.FromName = name

' 將收信人的資料加入元件
msg.AddRecipient recipient

' 設定信件的主題
msg.Subject = subject

' 設定信件的主體內容
msg.body = body

' 送出表單資料為電子郵件 ,並指定送信伺服器 SMTP
if not msg.Send("mail.you.com" ) then
Response.write "<pre>" & msg.log & "</pre>"
else
Response.write "信件成功寄出!"
end if

%>
</body>
</html>


以上的程式是基本的 JMail 搭配表單寄信的程式碼，您可以依您的需要自行修改；您可以參考完整的使用說明書自行設計。